Initial Commit

Signed-off-by: Marcel Müller <neikos@neikos.email>

flake.nix

@@ -0,0 +1,96 @@
+{
+  description = "The Theater Rust library";
+  inputs = {
+    nixpkgs.url = "nixpkgs/nixos-24.11";
+    flake-utils = {
+      url = "github:numtide/flake-utils";
+    };
+    crane = {
+      url = "github:ipetkov/crane";
+    };
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+      };
+    };
+  };
+
+  outputs = {  nixpkgs, crane, flake-utils, rust-overlay, ... }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [ (import rust-overlay) ];
+        };
+
+        rustTarget = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+        unstableRustTarget = pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.default.override {
+          extensions = [ "rust-src" "miri" "rustfmt" ];
+        });
+        craneLib = (crane.mkLib pkgs).overrideToolchain rustTarget;
+        unstableCraneLib = (crane.mkLib pkgs).overrideToolchain unstableRustTarget;
+
+        tomlInfo = craneLib.crateNameFromCargoToml { cargoToml = ./Cargo.toml; };
+        inherit (tomlInfo) version;
+        src = ./.;
+
+        rustfmt' = pkgs.writeShellScriptBin "rustfmt" ''
+          exec "${unstableRustTarget}/bin/rustfmt" "$@"
+        '';
+
+        cargoArtifacts = craneLib.buildDepsOnly {
+          inherit src;
+          cargoExtraArgs = "--all-features --all";
+        };
+
+        cloudmqtt = craneLib.buildPackage {
+          inherit cargoArtifacts src version;
+          cargoExtraArgs = "--all-features --all";
+        };
+
+      in
+      rec {
+        checks = {
+          inherit cloudmqtt;
+
+          cloudmqtt-clippy = craneLib.cargoClippy {
+            inherit cargoArtifacts src;
+            cargoExtraArgs = "--all --all-features";
+            cargoClippyExtraArgs = "-- --deny warnings";
+          };
+
+          cloudmqtt-fmt = unstableCraneLib.cargoFmt {
+            inherit src;
+          };
+        };
+
+        packages.cloudmqtt = cloudmqtt;
+        packages.default = packages.cloudmqtt;
+
+        apps.cloudmqtt = flake-utils.lib.mkApp {
+          name = "cloudmqtt";
+          drv = cloudmqtt;
+        };
+        apps.default = apps.cloudmqtt;
+
+        devShells.default = devShells.cloudmqtt;
+        devShells.cloudmqtt = pkgs.mkShell {
+          buildInputs = [ ];
+
+          nativeBuildInputs = [
+            rustfmt'
+            unstableRustTarget
+
+            pkgs.cargo-msrv
+            pkgs.cargo-deny
+            pkgs.cargo-expand
+            pkgs.cargo-bloat
+            pkgs.cargo-fuzz
+
+            pkgs.gitlint
+          ];
+        };
+      }
+    );
+}