{
  inputs = {
    nixpkgs.url = "nixpkgs/nixpkgs-unstable";
  };

  outputs =
    inputs:
    let
      forAllSystems =
        f:
        inputs.nixpkgs.lib.genAttrs [
          "x86_64-linux"
          "aarch64-linux"
        ] (system: f (import inputs.nixpkgs { inherit system; }));
    in
    {
      packages = forAllSystems (
        pkgs:

        let
          lanshare = pkgs.rustPlatform.buildRustPackage (finalAttrs: {
            pname = "lanshare";
            version = "0.1.0";
            src = ./lanshare;
            cargoHash = "sha256-rUTARzVTbi0/KNFUDRynOTioIZIhiZf4suqb9UqtvV4=";

            meta = {
              description = "A local screenshare application";
              mainProgram = "lanshare";
            };
          });
        in
        {
          inherit lanshare;
          gitlab-job-status = pkgs.writeShellApplication {
            name = "gitlab-job-status";
            runtimeInputs = [
              pkgs.curl
              pkgs.jq
              pkgs.git
              pkgs.ncurses
              pkgs.coreutils
            ];

            text = builtins.readFile ./gitlab-job-status;
          };

          migrate-workspace-deps = pkgs.writeShellApplication {
            name = "migrate-workspace-deps";
            runtimeInputs = [
              pkgs.jq
              pkgs.git
              pkgs.yq
            ];

            text = builtins.readFile ./migrate-workspace-deps;
          };
        }
      );
    };
}